Option explicit

const strFirma = ""  ' wenn dieser Wert gefüllt ist, wird die Firma erzwungen !

dim objOU, str_nachname, str_vorname, str_displayname, str_rdn, obj, Update, str_company

Sub usage()
	Dim Nachricht
	Nachricht             = "!------------------------------------------------------------------!" & vbCrLf
	Nachricht = Nachricht & "! Skript zum Korrigieren der Active Directory Displaynamen         !" & vbCrLf
	Nachricht = Nachricht & "! Stand: 05. Oktober 2003                                          !" & vbCrLf
	Nachricht = Nachricht & "! Autor:  frank.carius@netatwork.de                                !" & vbCrLf
	Nachricht = Nachricht & "!                                                                  !" & vbCrLf
	Nachricht = Nachricht & "!  Entfernt (*) aus dem Displayname                                !" & vbCrLf
	Nachricht = Nachricht & "!  Addiert  (firma)                                                !" & vbCrLf
	Nachricht = Nachricht & "!                                                                  !" & vbCrLf
	Nachricht = Nachricht & "! Aufruf: addfirma.vbs LDAPPfad der OU                             !" & vbCrLf
	Nachricht = Nachricht & "! Beispiel: addfirma.vbs OU=TestOU,DC=Entwicklung,DC=net           !" & vbCrLf
	Nachricht = Nachricht & "! Nicht erlaubte Sonderzeichen:  sind Backslash und Komma          !" & vbCrLf
	Nachricht = Nachricht & "!------------------------------------------------------------------!" & vbCrLf
	wscript.echo Nachricht
	wscript.quit(0)
End Sub


If (wscript.Arguments.length = 0) Then
	Call usage
	wscript.quit(1)
End If
If (InStr(wscript.Arguments(0),"?") > 0) Then
	Call usage
	wscript.quit(1)
End If

wscript.echo "addfirma.vbs: Gestartet:--- Ziel OU: " & wscript.Arguments(0)

Set objOU = GetObject("LDAP://" & wscript.Arguments(0))
For Each obj in objOU
	if obj.class = "User" then
		update = false
		wscript.echo "addfirma.vbs:Objekt ----------------- Originalwerte --------------------"
		wscript.echo "addfirma.vbs:Objekt CN            = " & obj.cn
		str_nachname = obj.sn
		wscript.echo "addfirma.vbs:   Nachname           =" & str_nachname
		str_vorname = trim(obj.givenName)
		wscript.echo "addfirma.vbs:   Vorname            =" & str_vorname
		str_displayname = trim(obj.displayname)
		wscript.echo "addfirma.vbs:   Displayname        =" & str_displayname
		if strFirma <> "" then 
			str_company = strFirma
		else 
			str_company = trim(obj.company)
		end if 
		if str_company <> "" then 
			str_company  = " (" & str_company & ")"  ' Klammern drumrum
		end if
		wscript.echo "addfirma.vbs:   Firma              =" & str_company
		
		if len(str_displayname) = 0 then
			' Displayname ist leer, also gehe ich von gefüllten Feldern für Vorname, Nachname (Firma) aus.
			str_displayname = str_nachname & ", " & str_vorname & str_company
		elseif instr(str_displayname,"(") = 0 then
			' Displayname ist gefüllt, aber enth&auml;lt noch keine Firma als Suffix
			str_displayname = str_displayname & str_company	
		else
			' Displayname ist gefüllt, und enth&auml;lt anscheinend "(" und damit eine Firma.
			str_displayname = trim(left(str_displayname ,instr(str_displayname,"(")-1))  & str_company
		end if 

		wscript.echo "addfirma.vbs:Objekt ----------------- NEUER Werte --------------------"


		if str_displayname <> obj.displayname then 
			wscript.echo "addfirma.vbs:  Displayname Neu    =" & str_displayname
			obj.displayname = str_displayname
			if strFirma <> "" then 
				obj.company = strFirma
			end if 
			obj.SetInfo				
			wscript.echo "addfirma.vbs: Geschrieben"
		else
		
		end if
	end if
Next

wscript.echo "addfirma.vbs: beendet"
wscript.quit(0)